描述

主條目：如何在 Arduino 中使用 NRF24L01 模塊

擁有兩個(gè)或多個(gè) Arduino 板能夠在一定距離內(nèi)以無線方式相互通信打開了許多可能性，例如遠(yuǎn)程監(jiān)控傳感器數(shù)據(jù)、控制機(jī)器人、家庭自動(dòng)化等等。NRF24L01 是一種良好、可靠且廉價(jià)的解決方案。

NRF24L01+ 是 NRF24L01 的更新版本，能夠額外提供 250kbps 的空中數(shù)據(jù)速率，而沒有“+”的只有 1Mbps 和 2Mbps。只要使用 1 或 2 MBps 作為數(shù)據(jù)速率，兩個(gè)版本都可以混合使用。

NRF24L01 與 NRF24L01+PA+LNA

NRF24L01 模塊嚴(yán)格需要 3.3V，但邏輯引腳可承受 5V。這就是為什么我們推薦使用 NRF24L01 適配器作為穩(wěn)壓器，保持電壓穩(wěn)定，應(yīng)用濾波和降低噪音。

第一個(gè)版本（左側(cè)）使用板載天線。這允許更緊湊的突破版本。使用此版本，您將能夠在 100 米的距離內(nèi)進(jìn)行通信（室內(nèi)范圍，尤其是穿過墻壁，將略微減弱）。我們將它用于接收器。

第二個(gè)版本（右側(cè)）集成了 PA、LNA 和收發(fā)切換電路。該范圍擴(kuò)展芯片與外部天線一起幫助模塊達(dá)到約 1000m。我們將它用于發(fā)射器。

該適配器對兩個(gè)版本的工作方式相同，并且具有與原始板相同的引腳排列。

接線圖

NRF24L01 模塊使用 SPI 協(xié)議與 Arduino 通信。該模塊充當(dāng) SPI 從機(jī)，這意味著它只能與具有專用 SPI 通信線路的設(shè)備一起使用。這意味著MOSI 、MISO和SCK引腳必須連接到微控制器上相應(yīng)的引腳。我們使用了 Arduino Nano，這些引腳如下：

• MOSI ：Arduino Nano D11

• 味噌：Arduino Nano D12

• SCK : Arduino Nano D13

CE和CSN引腳可以分別連接到 Arduino Nano D9 和 D10（您可以使用任何引腳）。但是，D10 引腳是一個(gè)特殊引腳，必須將其設(shè)置為OUTPUT才能使Arduino Nano作為 SPI 主機(jī)運(yùn)行。如果您使用不同的 Arduino 板，建議在繼續(xù)之前查看Arduino 官方文檔。

帶有 NRF24L01 的 Arduino Nano 接線

?

注意：您需要制作兩個(gè)這樣的電路。一個(gè)充當(dāng)發(fā)射器，另一個(gè)充當(dāng)接收器。兩者的接線是相同的。

為 nRF24L01 安裝 Arduino 庫

該庫將為您提供與模塊進(jìn)行通信的接口，從而為您節(jié)省大量時(shí)間，并提供經(jīng)過社區(qū)多年測試和改進(jìn)的強(qiáng)大代碼庫。您可以從我們的官方存儲(chǔ)庫下載該庫。

要導(dǎo)入它，請打開 Arduino IDE，轉(zhuǎn)到 Sketch > Include Library > Add.ZIP Library，然后選擇剛剛下載的文件。

?

然后你可以簡單地使用include語句：

#include "RF24.h"
#include "nRF24L01.h"

它將包含具有與模塊交互的預(yù)定義函數(shù)的庫。

發(fā)射器 Arduino 代碼

我們定義了一個(gè)結(jié)構(gòu)（稱為payload ），它將每INTERVAL_MS_TRANSMISSION毫秒發(fā)送一次。

• setup()函數(shù)使用提供的配置啟動(dòng)模塊作為發(fā)送器。

• loop()函數(shù)將負(fù)責(zé)更新有效負(fù)載值并發(fā)送它們。

#include "SPI.h"
#include "RF24.h"
#include "nRF24L01.h"

#define CE_PIN 9
#define CSN_PIN 10

#define INTERVAL_MS_TRANSMISSION 250

RF24 radio(CE_PIN, CSN_PIN);

const byte address[6] = "00001";

//NRF24L01 buffer limit is 32 bytes (max struct size)
struct payload {
  byte data1;
  char data2;
};

payload payload;

void setup()
{
  Serial.begin(115200);

  radio.begin();

  //Append ACK packet from the receiving radio back to the transmitting radio
  radio.setAutoAck(false); //(true|false)
  //Set the transmission datarate
  radio.setDataRate(RF24_250KBPS); //(RF24_250KBPS|RF24_1MBPS|RF24_2MBPS)
  //Greater level = more consumption = longer distance
  radio.setPALevel(RF24_PA_MAX); //(RF24_PA_MIN|RF24_PA_LOW|RF24_PA_HIGH|RF24_PA_MAX)
  //Default value is the maximum 32 bytes
  radio.setPayloadSize(sizeof(payload));
  //Act as transmitter
  radio.openWritingPipe(address);
  radio.stopListening();
}

void loop()
{
  payload.data1 = 123;
  payload.data2 = 'x';

  radio.write(&payload, sizeof(payload));

  Serial.print("Data1:");
  Serial.println(payload.data1);

  Serial.print("Data2:");
  Serial.println(payload.data2);

  Serial.println("Sent");

  delay(INTERVAL_MS_TRANSMISSION);
}

接收器 Arduino 代碼

我們將監(jiān)聽發(fā)送器中定義的結(jié)構(gòu)（稱為payload ）。在INTERVAL_MS_SIGNAL_LOST毫秒后，連接將被視為丟失。

• setup()函數(shù)使用提供的配置啟動(dòng)模塊作為接收器。

• loop()函數(shù)將負(fù)責(zé)偵聽有效負(fù)載并進(jìn)行處理。

• lostConnection()函數(shù)將處理丟失的連接以防止不必要的行為。

#include "SPI.h"
#include "RF24.h"
#include "nRF24L01.h"

#define CE_PIN 9
#define CSN_PIN 10

#define INTERVAL_MS_SIGNAL_LOST 1000
#define INTERVAL_MS_SIGNAL_RETRY 250

RF24 radio(CE_PIN, CSN_PIN);

const byte address[6] = "00001";

//NRF24L01 buffer limit is 32 bytes (max struct size)
struct payload {
  byte data1;
  char data2;
};

payload payload;

unsigned long lastSignalMillis = 0;

void setup()
{
  Serial.begin(115200);

  radio.begin();

  //Append ACK packet from the receiving radio back to the transmitting radio
  radio.setAutoAck(false); //(true|false)
  //Set the transmission datarate
  radio.setDataRate(RF24_250KBPS); //(RF24_250KBPS|RF24_1MBPS|RF24_2MBPS)
  //Greater level = more consumption = longer distance
  radio.setPALevel(RF24_PA_MIN); //(RF24_PA_MIN|RF24_PA_LOW|RF24_PA_HIGH|RF24_PA_MAX)
  //Default value is the maximum 32 bytes1
  radio.setPayloadSize(sizeof(payload));
  //Act as receiver
  radio.openReadingPipe(0, address);
  radio.startListening();
}

void loop()
{
  unsigned long currentMillis = millis();

  if (radio.available() > 0) {
    radio.read(&payload, sizeof(payload));

    Serial.println("Received");

    Serial.print("Data1:");
    Serial.println(payload.data1);

    Serial.print("Data2:");
    Serial.println(payload.data2);

    lastSignalMillis = currentMillis;
  }

  if (currentMillis - lastSignalMillis > INTERVAL_MS_SIGNAL_LOST) {
    lostConnection();
  }
}

void lostConnection()
{
  Serial.println("We have lost connection, preventing unwanted behavior");

  delay(INTERVAL_MS_SIGNAL_RETRY);
}

測試

請記住，我們必須構(gòu)建兩個(gè)具有相同接線的電路。

一方面，我們將上傳發(fā)射器代碼。它將生成消息有效負(fù)載并在每個(gè)INTERVAL_MS_TRANSMISSION發(fā)送它。

另一方面，我們將上傳接收方代碼。它將偵聽消息有效負(fù)載并進(jìn)行處理。串行監(jiān)視器將輸出類似于：

?

最后一行表示連接丟失（在沒有信號的INTERVAL_MS_SIGNAL_LOST毫秒之后）。在我們的例子中，這是一種預(yù)期的行為。在現(xiàn)實(shí)生活中，由于許多已知和未知的原因，信號可能會(huì)丟失，我們應(yīng)該能夠控制它并采取糾正措施（在lostConnection()函數(shù)中）。