本案例使用按鈕依次切換8個輸出且可控制輸出通道，比如控制指示燈，可以輸入序號來點亮該序號指示燈，連接時鐘信號可以實現跑馬燈效果。點擊正向按鈕則正序依次切換指示燈，如此反復。點擊反向按鈕則逆序依次切換指示燈。

功能介紹

• 如果EN為FALSE，則所有輸出均為FALSE。輸入EN必須為TRUE，在E = TRUE時只有一個輸出Qn為TRUE。
• 當E = TRUE時，使用輸入UP從輸出Qn切換到Qn +1，而輸入DN將輸出Qn切換到Qn-1。
• 當E = TRUE時，可以由SET輸入和輸入IN值選擇主動輸出Q0..Q7。如SET=TRUE，IN=5將輸出Q5=TRUE，而所有其他輸出都設置為FALSE。
• 當E = TRUE時，輸入RST=TRUE將輸出Q0設置為TRUE，而所有其他輸出都設置為FALSE。
• 當E = TRUE時，狀態輸出總是顯示當前選擇了哪個輸出Qn；當E=FALSE時，狀態輸出保持不變，E再次變為TRUE時，Qn再次輸出。

SELECT_8源代碼

SELECT_8實現的是選擇器的功能，內部調用一個取模函數INC，詳見下面介紹取模運算（INC）以及其代碼。

01

取模運算(INC)

取模是除以兩個數字時查找余數的操作。因此，當你問“什么是2 mod 2？”時，你是在問 “當你把 2 除以 2 時，余數是多少？”

SELECT_8源代碼

FUNCTION_BLOCK "SELECT_8"
TITLE = 'SELECT_8'
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
   VAR_INPUT 
      E : Bool;
      SET : Bool;
      IN : Int;
      UP : Bool;
      DN : Bool;
      RST : Bool;
   END_VAR




   VAR_OUTPUT 
      Q0 : Bool;
      Q1 : Bool;
      Q2 : Bool;
      Q3 : Bool;
      Q4 : Bool;
      Q5 : Bool;
      Q6 : Bool;
      Q7 : Bool;
      STATE : Int;
   END_VAR




   VAR 
      last_up : Bool;
      last_dn : Bool;
   END_VAR








BEGIN


IF #RST THEN
  #STATE := 0;
ELSIF #SET THEN
  #STATE := #IN;
ELSIF #UP AND NOT #last_up THEN
  #STATE := "INC"(X := #STATE, D := 1, M := 7);
ELSIF #DN AND NOT #last_dn THEN
  #STATE := "INC"(X := #STATE, D := -1, M := 7);
END_IF;
#last_up := #UP;
#last_dn := #DN;


#Q0 := FALSE;
#Q1 := FALSE;
#Q2 := FALSE;
#Q3 := FALSE;
#Q4 := FALSE;
#Q5 := FALSE;
#Q6 := FALSE;
#Q7 := FALSE;


IF #E THEN
  CASE #STATE OF
    0:
      #Q0 := TRUE;
    1:
      #Q1 := TRUE;
    2:
      #Q2 := TRUE;
    3:
      #Q3 := TRUE;
    4:
      #Q4 := TRUE;
    5:
      #Q5 := TRUE;
    6:
      #Q6 := TRUE;
    7:
      #Q7 := TRUE;
  END_CASE;
END_IF;




END_FUNCTION_BLOCK

INC源代碼

FUNCTION "INC" : Int
{ S7_Optimized_Access := 'TRUE' }
VERSION : 0.1
   VAR_INPUT 
      X : Int;
      D : Int;
      M : Int;
   END_VAR








BEGIN


#INC := (#X + #D + #M + 1) MOD (#M + 1);
END_FUNCTION